以前の記事でVBAを利用して画面のキャプチャを行う記事を書いた。その中でアクティブな画面のキャプチャを取得するところで不具合があるケースに出くわしたので改善策を考えてみた。
現象はIE11で発生して、キャプチャした結果が枠だけ取れて中が真っ白になってしまっていた。そこでトリミングを行う方法で回避を行った。一時的に画像を保存したりすることになるのでいまいちな気もするけど、まぁ仕方ない・・・。
'----------以前の記事に追加した部分 -------
'------------↓↓↓ ActiveWindowのみのコピーのために実装 ------------
Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal ms As Long)
Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hWnd As Long) As Long
Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
Private Declare PtrSafe Function GetClipBoardData Lib "user32" Alias "GetClipboardData" (ByVal wFormat As Long) As Long
Private Declare PtrSafe Function CopyImage Lib "user32" (ByVal handle As Long, ByVal un1 As Long, ByVal n1 As Long, ByVal n2 As Long, ByVal un2 As Long) As Long
Private Const CF_BITMAP = 2
Private Const PICTYPE_BITMAP = 1
Private Const IMAGE_BITMAP = 0
Private Const LR_COPYRETURNORG = &H4
'図の中の文字が少ない場合の精度UP処理用
Private Const CST_STR_F = "F" '最後に付け足す文字
Private Const CST_INT_F = 5 'CST_STR_Fの個数
Private Function GetBitMap() As IPictureDisp
Dim iid As GUID
Dim Pic As PicBmp
Dim ObjPic As IPictureDisp
Dim hBitmap As Long
Dim CopyBitmap As Long
With iid
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With
If OpenClipboard(0&) = 0 Then
MsgBox "クリップボードを開けませんでした"
Exit Function
End If
hBitmap = GetClipBoardData(CF_BITMAP)
If hBitmap = 0 Then
CloseClipboard
Exit Function
End If
CopyBitmap = CopyImage(hBitmap, _
IMAGE_BITMAP, 0, 0, _
LR_COPYRETURNORG)
CloseClipboard
With Pic
.Size = Len(Pic)
.Type = PICTYPE_BITMAP
.hBmp = CopyBitmap
End With
OleCreatePictureIndirect Pic, iid, 1, ObjPic
Set GetBitMap = ObjPic
End Function
'------------ ↑↑↑ ActiveWindowのみのコピーのために実装 ------------
Private Sub sample()
Dim r As Long
Dim Pic As IPictureDisp
Dim strTmpFilePath As String
'テストのためのスリープ
Sleep 3000
'ActiveWindowのキャプチャの時に不具合が発生することがあり、IE11では画面が白くなってしまった
'画面全体のキャプチャを行い、一度保存したのちにトリミングを行う
Set Pic = CaptureScreen()
strTmpFilePath = ThisWorkbook.Path & "\temp_FullScreen_" & Format(Now(), "yyyyMMddhhmmss") & ".bmp"
Call SavePicture(Pic, strTmpFilePath)
' Get a handle to the active/foreground window.
Dim hWndActive As Long
hWndActive = GetForegroundWindow()
' Get the dimensions of the window.
Dim RectActive As rect
r = GetWindowRect(hWndActive, RectActive)
Dim cxScreen As Long, cyScreen As Long
cxScreen = GetSystemMetrics(SM_CXSCREEN)
cyScreen = GetSystemMetrics(SM_CYSCREEN)
Dim top As Single, bottom As Single, left As Single, right As Single
top = RectActive.top / cyScreen
bottom = (cyScreen - RectActive.bottom) / cyScreen
left = RectActive.left / cxScreen
right = (cxScreen - RectActive.right) / cxScreen
'トリミングをする画像と保存先を指定
Call fncPicTrimming(strTmpFilePath, "C:\Users\username\Desktop\新しいフォルダー\screen.bmp", top, bottom, left, right)
'一時ファイルを削除
Kill strTmpFilePath
End Sub
Private Function fncPicTrimming(strTargetFile As String, strPass As String, sglT As Single, sglB As Single, sglL As Single, sglR As Single) As String
Dim strWrkPass As String
fncPicTrimming = ""
Application.ScreenUpdating = False
'トリミング前保存場所
strWrkPass = ThisWorkbook.Path & "\temp_Step1_" & Format(Now(), "yyyyMMddhhmmss") & ".bmp"
'取得画像をそのまま処理すると画像がボケることがあるので、一度フォームに貼付→再保存する
UserForm1.Picture = LoadPicture(strTargetFile)
SavePicture UserForm1.Picture, strWrkPass
UserForm1.Picture = LoadPicture()
'画像の挿入（作業用のワークシートを用意する）
ActiveSheet.Pictures.Insert(strWrkPass).Select
'ファイルを削除
Kill strWrkPass
'図のサイズのリセットを行っておく
With Application.CommandBars
If .GetEnabledMso("PictureResetAndSize") = True Then .ExecuteMso "PictureResetAndSize"
End With
'変更前の値を保持
Dim sHeight, sWidth
sHeight = Selection.ShapeRange.Height
sWidth = Selection.ShapeRange.Width
Selection.ShapeRange.LockAspectRatio = msoFalse
'トリミング実行 トリミングは実際に「マクロの記録」を利用して、その値をそのままコードへ（小数点をカットしないこと！）
Selection.ShapeRange.PictureFormat.CropTop = sglT * sHeight
Selection.ShapeRange.PictureFormat.CropBottom = sglB * sHeight
Selection.ShapeRange.PictureFormat.CropLeft = sglL * sWidth
Selection.ShapeRange.PictureFormat.CropRight = sglR * sWidth
'トリミング後保存場所
'strWrkPass = ThisWorkbook.Path + "\image2.bmp"
'トリミング後の画像をクリップボードへコピーし、それを保存（excelではこれしか方法がなさそう）
Selection.CopyPicture Appearance:=xlScreen, Format:=xlBitmap
SavePicture GetBitMap(), strPass
Selection.Delete
Application.ScreenUpdating = True
fncPicTrimming = strWrkPass
End Function
'---念のため全文---
'******************************************************************************
'* 【参考元】
'* Microsoft Support
'* 画面、フォーム、ウィンドウを取り込んで印刷する方法
'* 文書番号: 161299
'* http://support.microsoft.com/kb/161299/ja
'******************************************************************************
Option Explicit
Option Base 0
Private Type PALETTEENTRY
peRed As Byte
peGreen As Byte
peBlue As Byte
peFlags As Byte
End Type
Private Type LOGPALETTE
palVersion As Integer
palNumEntries As Integer
palPalEntry(255) As PALETTEENTRY ' Enough for 256 colors.
End Type
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type
Private Type rect
left As Long
top As Long
right As Long
bottom As Long
End Type
Private Type PicBmp
Size As Long
Type As Long
hBmp As Long
hPal As Long
Reserved As Long
End Type
Private Const RASTERCAPS As Long = 38
Private Const RC_PALETTE As Long = &H100
Private Const SIZEPALETTE As Long = 104
Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal ms As Long)
Private Declare PtrSafe Function CreateCompatibleDC Lib "gdi32" (ByVal hDc As Long) As Long
Private Declare PtrSafe Function CreateCompatibleBitmap Lib "gdi32" (ByVal hDc As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
Private Declare PtrSafe Function GetDeviceCaps Lib "gdi32" (ByVal hDc As Long, ByVal iCapabilitiy As Long) As Long
Private Declare PtrSafe Function GetSystemPaletteEntries Lib "gdi32" (ByVal hDc As Long, ByVal wStartIndex As Long, ByVal wNumEntries As Long, lpPaletteEntries As PALETTEENTRY) As Long
Private Declare PtrSafe Function CreatePalette Lib "gdi32" (lpLogPalette As LOGPALETTE) As Long
Private Declare PtrSafe Function SelectObject Lib "gdi32" (ByVal hDc As Long, ByVal hObject As Long) As Long
Private Declare PtrSafe Function BitBlt Lib "gdi32" (ByVal hDCDest As Long, ByVal XDest As Long, ByVal YDest As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hDCSrc As Long, ByVal XSrc As Long, ByVal YSrc As Long, ByVal dwRop As Long) As Long
Private Declare PtrSafe Function DeleteDC Lib "gdi32" (ByVal hDc As Long) As Long
Private Declare PtrSafe Function GetForegroundWindow Lib "user32" () As Long
Private Declare PtrSafe Function SelectPalette Lib "gdi32" (ByVal hDc As Long, ByVal hPalette As Long, ByVal bForceBackground As Long) As Long
Private Declare PtrSafe Function RealizePalette Lib "gdi32" (ByVal hDc As Long) As Long
Private Declare PtrSafe Function GetWindowDC Lib "user32" (ByVal hWnd As Long) As Long
Private Declare PtrSafe Function GetDC Lib "user32" (ByVal hWnd As Long) As Long
Private Declare PtrSafe Function GetWindowRect Lib "user32" (ByVal hWnd As Long, lpRect As rect) As Long
Private Declare PtrSafe Function ReleaseDC Lib "user32" (ByVal hWnd As Long, ByVal hDc As Long) As Long
Private Declare PtrSafe Function GetDesktopWindow Lib "user32" () As Long
Private Declare PtrSafe Function OleCreatePictureIndirect Lib "oleaut32.dll" (PicDesc As PicBmp, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
Private Declare PtrSafe Function GetActiveWindow Lib "user32" () As Long
Private Const vbPicTypeBitmap As Long = 1
Private Const vbSrcCopy As Long = &HCC0020
Private Const SM_CXSCREEN As Long = 0
Private Const SM_CYSCREEN As Long = 1
Private Declare PtrSafe Function GetSystemMetrics Lib "user32" (ByVal nIndex As Long) As Long
'------------↓↓↓ ActiveWindowのみのコピーのために実装 ------------
Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hWnd As Long) As Long
Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
Private Declare PtrSafe Function GetClipBoardData Lib "user32" Alias "GetClipboardData" (ByVal wFormat As Long) As Long
Private Declare PtrSafe Function CopyImage Lib "user32" (ByVal handle As Long, ByVal un1 As Long, ByVal n1 As Long, ByVal n2 As Long, ByVal un2 As Long) As Long
Private Const CF_BITMAP = 2
Private Const PICTYPE_BITMAP = 1
Private Const IMAGE_BITMAP = 0
Private Const LR_COPYRETURNORG = &H4
'図の中の文字が少ない場合の精度UP処理用
Private Const CST_STR_F = "F" '最後に付け足す文字
Private Const CST_INT_F = 5 'CST_STR_Fの個数
Private Function GetBitMap() As IPictureDisp
Dim iid As GUID
Dim Pic As PicBmp
Dim ObjPic As IPictureDisp
Dim hBitmap As Long
Dim CopyBitmap As Long
With iid
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With
If OpenClipboard(0&) = 0 Then
MsgBox "クリップボードを開けませんでした"
Exit Function
End If
hBitmap = GetClipBoardData(CF_BITMAP)
If hBitmap = 0 Then
CloseClipboard
Exit Function
End If
CopyBitmap = CopyImage(hBitmap, _
IMAGE_BITMAP, 0, 0, _
LR_COPYRETURNORG)
CloseClipboard
With Pic
.Size = Len(Pic)
.Type = PICTYPE_BITMAP
.hBmp = CopyBitmap
End With
OleCreatePictureIndirect Pic, iid, 1, ObjPic
Set GetBitMap = ObjPic
End Function
'------------ ↑↑↑ ActiveWindowのみのコピーのために実装 ------------
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' CreateBitmapPicture
' - Creates a bitmap type Picture object from a bitmap and
' palette.
'
' hBmp
' - Handle to a bitmap.
'
' hPal
' - Handle to a Palette.
' - Can be null if the bitmap doesn't use a palette.
'
' Returns
' - Returns a Picture object containing the bitmap.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Function CreateBitmapPicture(ByVal hBmp As Long, ByVal hPal As Long) As IPictureDisp
' Fill in with IDispatch Interface ID.
Dim IID_IDispatch As GUID
With IID_IDispatch
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With
' Fill Pic with necessary parts.
Dim Pic As PicBmp
With Pic
.Size = Len(Pic) ' Length of structure.
.Type = vbPicTypeBitmap ' Type of Picture (bitmap).
.hBmp = hBmp ' Handle to bitmap.
.hPal = hPal ' Handle to palette (may be null).
End With
' Create Picture object.
Dim IPic As IPicture
Dim r As Long
r = OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)
' Return the new Picture object.
Set CreateBitmapPicture = IPic
End Function
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' CaptureWindow
' - Captures any portion of a window.
'
' hWndSrc
' - Handle to the window to be captured.
'
' Client
' - If True CaptureWindow captures from the client area of the
' window.
' - If False CaptureWindow captures from the entire window.
'
' LeftSrc, TopSrc, WidthSrc, HeightSrc
' - Specify the portion of the window to capture.
' - Dimensions need to be specified in pixels.
'
' Returns
' - Returns a Picture object containing a bitmap of the specified
' portion of the window that was captured.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Function CaptureWindow(ByVal hWndSrc As Long, ByVal Client As Boolean, ByVal LeftSrc As Long, ByVal TopSrc As Long, ByVal WidthSrc As Long, ByVal HeightSrc As Long) As IPictureDisp
Dim r As Long
' Depending on the value of Client get the proper device context.
Dim hDCSrc As Long
hDCSrc = IIf(Client, GetDC(hWndSrc), GetWindowDC(hWndSrc))
' Create a memory device context for the copy process.
Dim hDCMemory As Long
hDCMemory = CreateCompatibleDC(hDCSrc)
' Create a bitmap and place it in the memory DC.
Dim hBmp As Long, hBmpPrev As Long
hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
hBmpPrev = SelectObject(hDCMemory, hBmp)
' Get screen properties.
Dim RasterCapsScrn As Long, HasPaletteScrn As Long, PaletteSizeScrn As Long
RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS) ' Raster capabilities.
HasPaletteScrn = RasterCapsScrn And RC_PALETTE ' Palette support.
PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE) ' Size of palette.
' If the screen has a palette make a copy and realize it.
Dim hPal As Long, hPalPrev As Long, LogPal As LOGPALETTE
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
' Create a copy of the system palette.
LogPal.palVersion = &H300
LogPal.palNumEntries = 256
r = GetSystemPaletteEntries(hDCSrc, 0, 256, LogPal.palPalEntry(0))
hPal = CreatePalette(LogPal)
' Select the new palette into the memory DC and realize it.
hPalPrev = SelectPalette(hDCMemory, hPal, 0)
r = RealizePalette(hDCMemory)
End If
' Copy the on-screen image into the memory DC.
r = BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, hDCSrc, LeftSrc, TopSrc, vbSrcCopy)
' Remove the new copy of the on-screen image.
hBmp = SelectObject(hDCMemory, hBmpPrev)
' If the screen has a palette get back the palette that was
' selected in previously.
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
hPal = SelectPalette(hDCMemory, hPalPrev, 0)
End If
' Release the device context resources back to the system.
r = DeleteDC(hDCMemory)
r = ReleaseDC(hWndSrc, hDCSrc)
' Call CreateBitmapPicture to create a picture object from the
' bitmap and palette handles. Then return the resulting picture
' object.
Set CaptureWindow = CreateBitmapPicture(hBmp, hPal)
End Function
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' CaptureScreen
' - Captures the entire screen.
'
' Returns
' - Returns a Picture object containing a bitmap of the screen.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Function CaptureScreen() As IPictureDisp
' Get a handle to the desktop window.
Dim hWndScreen As Long
hWndScreen = GetDesktopWindow()
Dim cxScreen As Long, cyScreen As Long
cxScreen = GetSystemMetrics(SM_CXSCREEN)
cyScreen = GetSystemMetrics(SM_CYSCREEN)
' Call CaptureWindow to capture the entire desktop give the handle
' and return the resulting Picture object.
Set CaptureScreen = CaptureWindow(hWndScreen, False, 0, 0, cxScreen, cyScreen)
End Function
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' CaptureActiveWindow
' - Captures the currently active window on the screen.
'
' Returns
' - Returns a Picture object containing a bitmap of the active
' window.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Function CaptureActiveWindow() As IPictureDisp
Dim r As Long
' Get a handle to the active/foreground window.
Dim hWndActive As Long
hWndActive = GetForegroundWindow()
'hWndActive = GetActiveWindow()
' Get the dimensions of the window.
Dim RectActive As rect
r = GetWindowRect(hWndActive, RectActive)
' Call CaptureWindow to capture the active window given its
' handle and return the Resulting Picture object.
Set CaptureActiveWindow = CaptureWindow(hWndActive, False, 0, 0, RectActive.right - RectActive.left, RectActive.bottom - RectActive.top)
End Function
Public Sub SavePictureOfActiveWindow()
Dim Pic As IPictureDisp
Set Pic = CaptureActiveWindow()
Call SavePicture(Pic, "C:\Users\username\Desktop\新しいフォルダー\activewindow.bmp")
End Sub
Public Sub SavePictureOfScreen()
Dim Pic As IPictureDisp
Set Pic = CaptureScreen()
Call SavePicture(Pic, "C:\Users\username\Desktop\新しいフォルダー\screen.bmp")
End Sub
Private Sub sample()
Dim r As Long
Dim Pic As IPictureDisp
Dim strTmpFilePath As String
'テストのためのスリープ
Sleep 3000
'ActiveWindowのキャプチャの時に不具合が発生することがあり、IE11では画面が白くなってしまった
'画面全体のキャプチャを行い、一度保存したのちにトリミングを行う
Set Pic = CaptureScreen()
strTmpFilePath = ThisWorkbook.Path & "\temp_FullScreen_" & Format(Now(), "yyyyMMddhhmmss") & ".bmp"
Call SavePicture(Pic, strTmpFilePath)
' Get a handle to the active/foreground window.
Dim hWndActive As Long
hWndActive = GetForegroundWindow()
' Get the dimensions of the window.
Dim RectActive As rect
r = GetWindowRect(hWndActive, RectActive)
Dim cxScreen As Long, cyScreen As Long
cxScreen = GetSystemMetrics(SM_CXSCREEN)
cyScreen = GetSystemMetrics(SM_CYSCREEN)
Dim top As Single, bottom As Single, left As Single, right As Single
top = RectActive.top / cyScreen
bottom = (cyScreen - RectActive.bottom) / cyScreen
left = RectActive.left / cxScreen
right = (cxScreen - RectActive.right) / cxScreen
'トリミングをする画像と保存先を指定
Call fncPicTrimming(strTmpFilePath, "C:\Users\username\Desktop\新しいフォルダー\screen.bmp", top, bottom, left, right)
'一時ファイルを削除
Kill strTmpFilePath
End Sub
Private Function fncPicTrimming(strTargetFile As String, strPass As String, sglT As Single, sglB As Single, sglL As Single, sglR As Single) As String
Dim strWrkPass As String
fncPicTrimming = ""
Application.ScreenUpdating = False
'トリミング前保存場所
strWrkPass = ThisWorkbook.Path & "\temp_Step1_" & Format(Now(), "yyyyMMddhhmmss") & ".bmp"
'取得画像をそのまま処理すると画像がボケることがあるので、一度フォームに貼付→再保存する
UserForm1.Picture = LoadPicture(strTargetFile)
SavePicture UserForm1.Picture, strWrkPass
UserForm1.Picture = LoadPicture()
'画像の挿入（作業用のワークシートを用意する）
ActiveSheet.Pictures.Insert(strWrkPass).Select
'ファイルを削除
Kill strWrkPass
'図のサイズのリセットを行っておく
With Application.CommandBars
If .GetEnabledMso("PictureResetAndSize") = True Then .ExecuteMso "PictureResetAndSize"
End With
'変更前の値を保持
Dim sHeight, sWidth
sHeight = Selection.ShapeRange.Height
sWidth = Selection.ShapeRange.Width
Selection.ShapeRange.LockAspectRatio = msoFalse
'トリミング実行 トリミングは実際に「マクロの記録」を利用して、その値をそのままコードへ（小数点をカットしないこと！）
Selection.ShapeRange.PictureFormat.CropTop = sglT * sHeight
Selection.ShapeRange.PictureFormat.CropBottom = sglB * sHeight
Selection.ShapeRange.PictureFormat.CropLeft = sglL * sWidth
Selection.ShapeRange.PictureFormat.CropRight = sglR * sWidth
'トリミング後保存場所
'strWrkPass = ThisWorkbook.Path + "\image2.bmp"
'トリミング後の画像をクリップボードへコピーし、それを保存（excelではこれしか方法がなさそう）
Selection.CopyPicture Appearance:=xlScreen, Format:=xlBitmap
SavePicture GetBitMap(), strPass
Selection.Delete
Application.ScreenUpdating = True
fncPicTrimming = strWrkPass
End Function
0 件のコメント:
コメントを投稿